meshcore-cli/flake.nix at main · meshcore-dev/meshcore-cli · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    inputs:
    inputs.flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = inputs.nixpkgs.legacyPackages.${system};

        lib = pkgs.lib;

        inherit (pkgs) python3Packages;

        meshcore = python3Packages.buildPythonPackage rec {
          pname = "meshcore";
          version = "2.3.5";
          pyproject = true;

          src = python3Packages.fetchPypi {
            inherit pname version;
            sha256 = "sha256-EUK0iFaCN2tpOL3XL2ejVLGz/gLTdvzPpvgBxETLL3w=";
          };

          build-system = [ python3Packages.hatchling ];

          dependencies = [
            python3Packages.bleak
            python3Packages.pycayennelpp
            python3Packages.pyserial-asyncio-fast
            python3Packages.pycryptodome
          ];

          pythonImportsCheck = [ "meshcore" ];
        };

        pyproject = lib.importTOML ./pyproject.toml;
        version = pyproject.project.version;
      in
      {
        packages.meshcore-cli = python3Packages.buildPythonPackage {
          pname = "meshcore-cli";
          inherit version;

          src = ./.;

          pyproject = true;

          nativeBuildInputs = [
            python3Packages.hatchling
            python3Packages.setuptools
            python3Packages.wheel
          ];

          propagatedBuildInputs = [
            meshcore
            python3Packages.click
            python3Packages.prompt_toolkit
            python3Packages.pyserial
            python3Packages.requests
            python3Packages.pycryptodome
          ];

          doCheck = false;
        };
      }
    );
}