java_telesign_enterprise/build.gradle at master · TeleSign/java_telesign_enterprise · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
plugins {
    id 'java'
    id 'signing'
    id 'maven-publish'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'checkstyle'
}

group = 'com.telesign.enterprise'
version = '4.0.1'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenCentral()
    maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
}

dependencies {
    implementation('com.telesign:telesign:[4.0.0, 5.0.0)')
    implementation 'com.google.code.gson:gson:[2.7,3.0)'
    testImplementation( group: 'junit', name: 'junit', version: '[4.1,)')
    testImplementation( group: 'com.squareup.okhttp3', name: 'mockwebserver', version: '[4.7.0,)')
}

checkstyle {
    toolVersion = '10.12.5'
    configFile = file("${rootDir}/config/checkstyle/checkstyle.xml")
    ignoreFailures = false
}

// Test configuration
test {
    useJUnit()
    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat "full"
        showStandardStreams = false
    }
}

// Task for linting
tasks.register('lint') {
    group = 'verification'
    description = 'Runs checkstyle linter'
    dependsOn 'checkstyleMain', 'checkstyleTest'
}

// Task for CI pipeline
tasks.register('ciTest') {
    group = 'verification'
    description = 'Runs tests and linter for CI/CD pipeline'
    dependsOn 'clean', 'test', 'lint'
}

// Task for release validation
tasks.register('validateRelease') {
    group = 'release'
    description = 'Validates code is ready for release'
    dependsOn 'ciTest', 'javadoc', 'sourcesJar', 'javadocJar'
    doLast {
        println "✓ Release validation completed successfully"
    }
}

jar {
    manifest {
        attributes 'Implementation-Version': project.version
    }
}

tasks.register('javadocJar', Jar) {
    from tasks.javadoc
    archiveClassifier.set('javadoc')
}

tasks.register('sourcesJar', Jar) {
    from sourceSets.main.allSource
    archiveClassifier.set('sources')
}

tasks.register("fatJar", Jar) {
    archiveClassifier.set("all")
    from sourceSets.main.output

    dependsOn configurations.runtimeClasspath
    from {
        configurations.runtimeClasspath.files.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

tasks.register('clearOldJar', Delete) {
    delete fileTree(dir: "build/libs", includes: [".bin"])
}


tasks.register('copyJar', Delete) {
    dependsOn("clearOldJar")
    from('fatJar')
    into('bin')
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifact javadocJar
            artifact sourcesJar
            artifact fatJar

            groupId = 'com.telesign.enterprise'
            artifactId = 'telesignenterprise'
            version = '4.0.1'

            pom {
                name = 'TeleSign Enterprise SDK'
                description = 'The Telesign Full-service Java SDK enhances the functionality of the Telesign Self-service Java SDK, providing access to a broader range of Telesign APIs. See our source code on GitHub (https://github.com/TeleSign/java_telesign_enterprise) for installation instructions and other details.'
                url = 'https://github.com/TeleSign/java_telesign_enterprise'

                scm {
                    connection = 'scm:git:https://github.com/TeleSign/java_telesign_enterprise.git'
                    developerConnection = 'scm:git:git@github.com:TeleSign/java_telesign_enterprise.git'
                    url = 'https://github.com/TeleSign/java_telesign_enterprise'
                }

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }
                developers {
                    developer {
                        name = 'TeleSign Corp.'
                        organizationUrl = 'https://www.telesign.com'
                    }
                }
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}