267666/WDRwithoutinter.hoc at main · ModelDBRepository/267666 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
//Created by Paulo Aguiar [pauloaguiar@fc.up.pt]

// CREATE WDR NEURON

begintemplate WDRwithoutinter

public soma, dendrite, hillock, axon

create soma, dendrite, hillock, axon

proc init() {

    create soma      // create a section called soma
    soma {
        nseg = 3     // define number of segments for discretization
        L = 20.0     // define length of compartment
        diam = 20.0  // define diameter of compartment

        //HH channels: iNat and iK
        insert HH2 {    // insert the density mechanism HH2 as defined by a .mod file, and set some of its parameter values
            gnabar_HH2 = 0.08
            gkbar_HH2 = 0.02
            vtraub_HH2 = -55.0
        }

        //intracellular Ca dynamics
        insert CaIntraCellDyn {
            depth_CaIntraCellDyn = 0.1
            cai_tau_CaIntraCellDyn = 1.0
            cai_inf_CaIntraCellDyn = 50.0e-6
        }

        //high-voltage activated long-lasting calcium current, L-type
        insert iCaL {
            pcabar_iCaL = 0.0001 //0.0001 - IMPORTANT: this current drives the (activity control) somatic iKCa current
        }

        //non-specific current dependent on intracellular calcium concentration
        insert iCaAN {
            gbar_iCaAN = 0.0 //0.0
        }

        //potassium current dependent on intracellular calcium concentration
        insert iKCa {
            gbar_iKCa = 0.002 //0.0001
        }

        //sodium persistent current
        insert iNaP {
            gnabar_iNaP = 0.0001 //0.0001
        }

        ek = -70.0    // set inversion potential of potassium for all mechanisms of soma

        Ra = 150.0    // set axial resistivity of soma

        insert pas   // pas (for passive) is a predefined mechanism modeling leak current through the membrane
        g_pas = 4.2e-5
        e_pas = -65.0
    }

    create dendrite
    dendrite {
        nseg = 5
        L = 500.0
        diam = 4.0

        //intracellular Ca dynamics
        insert CaIntraCellDyn {
            depth_CaIntraCellDyn = 0.1
            cai_tau_CaIntraCellDyn = 2.0
            cai_inf_CaIntraCellDyn = 50.0e-6
        }

        //high-voltage activated long-lasting calcium current, L-type
        insert iCaL {
            pcabar_iCaL = 3.0e-5 //3.0e-5 IMPORTANT: this current is important for activity control (drives the iKCa current)
        }

        //non-specific current dependent on intracellular calcium concentration
        insert iCaAN {
            gbar_iCaAN = 0.00007 //0.00007; This is a sensible parameter
            //higher values of gbar_iCaAN produce graphs similar to Silviloti et al 93
        }

        //potassium current dependent on intracellular calcium concentration
        insert iKCa {
            gbar_iKCa = 0.0025 //0.001; higher values place "holes" in the scatter plot, resulting from the cai bump after synaptic activation);
            //naturally, lower values will lead to increased firing
        }

        ek = -70.0

        Ra = 150.0

        insert pas
        g_pas = 4.2e-5
        e_pas = -65.0
    }


    create hillock
    hillock {
        nseg = 3
        L = 3
        diam(0:1) = 2.0:1.0    // diameter varies from 2 microns at the 0 end of the section to 1 micron at the other end

        //HH channels: iNa,t and iK
        insert HH2 {
            gnabar_HH2 = 0.1
            gkbar_HH2 = 0.04
            vtraub_HH2 = -55.0
        }

        Ra = 150.0

        insert pas
        g_pas = 4.2e-5
        e_pas = -65.0
    }

    create axon
    axon {
        nseg = 5
        L = 1000.0
        diam = 1.0

        //HH channels: iNa,t and iK
        insert HH2 {
            gnabar_HH2 = 0.1
            gkbar_HH2 = 0.04	//0.04
            vtraub_HH2 = -55
        }

        Ra = 150.0

        insert pas
        g_pas = 4.2e-5
        e_pas = -65.0
    }


    //CONNECTIONS
    soma connect hillock(0),1   // connect the 0 ending of hillock to the 1 ending of soma
    hillock connect axon(0),1
    soma connect dendrite(0),0

}


endtemplate WDRwithoutinter


//************************************************************************************
//UNITS
//Category									Variable			Units
//Time											t							[ms]
//Voltage										v							[mV]
//Current										i							[mA/cm2] (distributed)	[nA] (point process)
//Concentration							ko, ki, etc.	[mM]
//Specific capacitance			cm						[uf/cm2]
//Length										diam, L				[um]
//Conductance								g							[S/cm2] (distributed)	[uS] (point process)
//Cytoplasmic resistivity		Ra						[ohm cm]
//Resistance								Ri						[10E6 ohm]